c0ec17d188
* m4/Makefile.am: * m4/as-ac-expand.m4 (added): Correctly set installation dir for noarch python files so that it works on 64 bit.
50 lines
1.3 KiB
Plaintext
50 lines
1.3 KiB
Plaintext
dnl as-ac-expand.m4 0.2.1
|
|
dnl autostars m4 macro for expanding directories using configure's prefix
|
|
dnl thomas@apestaart.org
|
|
|
|
dnl AS_AC_EXPAND(VAR, CONFIGURE_VAR)
|
|
dnl example
|
|
dnl AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
|
|
dnl will set SYSCONFDIR to /usr/local/etc if prefix=/usr/local
|
|
dnl Note: when using $prefix or $exec_prefix, avoid it expanding to NONE
|
|
dnl by calling it like this:
|
|
dnl AS_AC_EXPAND(PYTHONLIBDIR, "\${exec_prefix}/lib/python$PYVER/site-packages")
|
|
|
|
AC_DEFUN([AS_AC_EXPAND],
|
|
[
|
|
EXP_VAR=[$1]
|
|
FROM_VAR=[$2]
|
|
|
|
dnl echo DEBUG: expand FROM_VAR $FROM_VAR
|
|
|
|
dnl first expand prefix and exec_prefix if necessary
|
|
prefix_save=$prefix
|
|
exec_prefix_save=$exec_prefix
|
|
|
|
dnl if no prefix given, then use /usr/local, the default prefix
|
|
if test "x$prefix" = "xNONE"; then
|
|
prefix="$ac_default_prefix"
|
|
fi
|
|
dnl if no exec_prefix given, then use prefix
|
|
if test "x$exec_prefix" = "xNONE"; then
|
|
exec_prefix=$prefix
|
|
fi
|
|
|
|
full_var="$FROM_VAR"
|
|
dnl loop until it doesn't change anymore
|
|
while true; do
|
|
dnl echo DEBUG: full_var: $full_var
|
|
new_full_var="`eval echo $full_var`"
|
|
if test "x$new_full_var" = "x$full_var"; then break; fi
|
|
full_var=$new_full_var
|
|
done
|
|
|
|
dnl clean up
|
|
full_var=$new_full_var
|
|
AC_SUBST([$1], "$full_var")
|
|
|
|
dnl restore prefix and exec_prefix
|
|
prefix=$prefix_save
|
|
exec_prefix=$exec_prefix_save
|
|
])
|