pkgname=whipper-git
pkgver=0.10.2.r0.g9564c7c
pkgrel=1
pkgdesc='CD-DA ripper prioritising accuracy over speed'
arch=('x86_64')
url='https://github.com/whipper-team/whipper'
license=('GPL-3.0-or-later')
depends=(
  'python'
  'python-discid'
  'python-musicbrainzngs'
  'python-mutagen'
  'python-pycdio'
  'python-gobject'
  'python-ruamel-yaml'
  'cdrdao'
  'cdparanoia'
  'flac'
  'gtk3'
  'libdiscid'
  'libsndfile'
  'sox'
)
makedepends=(
  'git'
  'gcc'
  'python-build'
  'python-installer'
  'python-setuptools'
  'python-setuptools-scm'
  'python-wheel'
)
checkdepends=(
  'python-pytest'
  'python-twisted'
)
optdepends=(
  'python-pillow: cover art embedding support'
  'python-docutils: man page generation'
)
provides=('whipper')
conflicts=('whipper')
source=('git+https://git.daemonlord.ru/benya/whipper-gui.git')
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/whipper-gui"
  git describe --long --tags --abbrev=7 | sed 's/^v//; s/\([^-]*-g\)/r\1/; s/-/./g'
}

build() {
  cd "$srcdir/whipper-gui"
  python -m build --wheel --no-isolation
}

check() {
  cd "$srcdir/whipper-gui"
  export HOME="$srcdir/home"
  mkdir -p "$HOME"
  pytest -q
}

package() {
  cd "$srcdir/whipper-gui"
  python -m installer --destdir="$pkgdir" dist/*.whl
}