diff --git a/ChangeLog b/ChangeLog
index dc2803a..31033eb 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,11 @@
+2009-09-06  Thomas Vander Stichele  <thomas at apestaart dot org>
+
+	* configure.ac:
+	* m4/Makefile.am:
+	* m4/as-ac-expand.m4 (added):
+	  Correctly set installation dir for noarch python files so that it
+	  works on 64 bit.
+
 2009-09-06  Thomas Vander Stichele  <thomas at apestaart dot org>
 
 	* morituri/program/cdrdao.py:
diff --git a/configure.ac b/configure.ac
index 5af2998..3dea217 100644
--- a/configure.ac
+++ b/configure.ac
@@ -27,9 +27,11 @@ dnl check for python
 AS_PATH_PYTHON(2.3)
 
 dnl check for where to install our python stuff
-dnl PYTHONLIBDIR=`$PYTHON -c "from distutils.sysconfig import get_python_lib; print get_python_lib()"`
 PYVER=[`$PYTHON -c "import sys ; print sys.version[:3]"`]
-PYTHONLIBDIR=\${libdir}/python$PYVER/site-packages
+
+dnl This is the best way of installing in an arch-independent location for now
+AS_AC_EXPAND(PYTHONLIBDIR, "\${exec_prefix}/lib/python$PYVER/site-packages")
+
 AC_MSG_NOTICE(Installing python code in $PYTHONLIBDIR)
 AC_SUBST(PYTHONLIBDIR)
 
diff --git a/m4/Makefile.am b/m4/Makefile.am
index 2b5978f..c7f3487 100644
--- a/m4/Makefile.am
+++ b/m4/Makefile.am
@@ -1 +1 @@
-EXTRA_DIST = as-version.m4 as-python.m4
+EXTRA_DIST = as-version.m4 as-python.m4 as-ac-expand.m4
diff --git a/m4/as-ac-expand.m4 b/m4/as-ac-expand.m4
new file mode 100644
index 0000000..e5b6e37
--- /dev/null
+++ b/m4/as-ac-expand.m4
@@ -0,0 +1,49 @@
+dnl as-ac-expand.m4 0.2.1
+dnl autostars m4 macro for expanding directories using configure's prefix
+dnl thomas@apestaart.org
+
+dnl AS_AC_EXPAND(VAR, CONFIGURE_VAR)
+dnl example
+dnl AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
+dnl will set SYSCONFDIR to /usr/local/etc if prefix=/usr/local
+dnl Note: when using $prefix or $exec_prefix, avoid it expanding to NONE
+dnl by calling it like this:
+dnl AS_AC_EXPAND(PYTHONLIBDIR, "\${exec_prefix}/lib/python$PYVER/site-packages")
+
+AC_DEFUN([AS_AC_EXPAND],
+[
+  EXP_VAR=[$1]
+  FROM_VAR=[$2]
+
+  dnl echo DEBUG: expand FROM_VAR $FROM_VAR
+
+  dnl first expand prefix and exec_prefix if necessary
+  prefix_save=$prefix
+  exec_prefix_save=$exec_prefix
+
+  dnl if no prefix given, then use /usr/local, the default prefix
+  if test "x$prefix" = "xNONE"; then
+    prefix="$ac_default_prefix"
+  fi
+  dnl if no exec_prefix given, then use prefix
+  if test "x$exec_prefix" = "xNONE"; then
+    exec_prefix=$prefix
+  fi
+
+  full_var="$FROM_VAR"
+  dnl loop until it doesn't change anymore
+  while true; do
+    dnl echo DEBUG: full_var: $full_var
+    new_full_var="`eval echo $full_var`"
+    if test "x$new_full_var" = "x$full_var"; then break; fi
+    full_var=$new_full_var
+  done
+
+  dnl clean up
+  full_var=$new_full_var
+  AC_SUBST([$1], "$full_var")
+
+  dnl restore prefix and exec_prefix
+  prefix=$prefix_save
+  exec_prefix=$exec_prefix_save
+])